function sxt_movy4sigmoid,noaa,tmin=tmin,tmax=tmax,$
	mkfile=mkfile,indir=indir,outdir=outdir,pauz=pauz,$
	c_table=c_table,big=big,sho_pfi=sho_pfi,nolimit=nolimit,$
	one_res=one_res

;+
; NAME
;	sxt_movy4sigmoid
; PURPOSE
;	Provide convenient way to review the SXT FFI movie for (a) the 
;	disk passage of a specific NOAA active region or (b) a specified
;	time interval.  Images may be flagged with a 0,1,2,3 or 4 for
;	future reference.  A .genx structure is saved with the movie
;	header information and a vector with the 0-4 flag values.
;
;	All functionality of STEPPER3 is available during movie viewing.
;	Including:	"r" overlays Stonyhurst and labels NOAA AR.
;			"o" overlays PFI observing region.
; CALLING SEQUENCE
;	out=sxt_movy4sigmoid(noaa,tmin=tmin,tmax=tmax,$
;	     mkfile=mkfile,indir=indir,outdir=outdir,pauz=pauz,$
;	     c_table=c_table,big=big,sho_pfi=sho_pfi,nolimit=nolimit)
; CALLING EXAMPLE
;	out=sxt_movy4sigmoid(tmin='20-Jan-97',indir='/yla/sxtmov23')
; ALTERNATIVE INPUTS
;	noaa, NOAA AR number
;	   or
;	tmin & tmax, start and ending times of desired time interval
;	in any format (default tmax is tmin + 24 hours)
; OPTIONAL KEYWORD INPUT
;	indir, movie directory (default: '/disk/hl1/ylegacy/sxtmov23')
;	/mkfile, write output .genx file (default: do not create file)
;	outdir, directory for output .genx file (default:  curdir())
;	pauz, pause between movie frames (default: 0.05 sec)
;	c_table, color_table number (default:  15, Stern Special)
;	/big, set movie display to 1024x1024 size.
;	/sho_pfi, overlay PFI FOV on every image.  (Slows stepper.)
;	/nolimit, load entire movie, otherwise load 100 at a time.
;       one_res, set keyword to 'HR' or 'QR' to display only one resolution.
; OUTPUT
;	Movie header structure with added tag .check giving the flag
;	(0-4) value for each movie image.
; OPTIONAL OUTPUT
;	.genx file written to outdir with structure
;	header and vector check.
; HISTORY
;	11-May-2009 LWA
;	27-May-2009 LWA  indir default: '/disk/sb1/sxtmov23'
;			Added header info.
;        1-Jun-2009 LWA  Added keyword one_res.
;	 2-Jun-2009 LWA  indir default: '/disk/hl1/ylegacy/sxtmov23'
;			Added protection against 1-day NAR.
;-

; Common block get_movy4nar contains the NOAA active region info.
common get_movy4nar,nar_data
if not_exist(nar_data) then rd_nar,'15-sep-91','15-dec-01',nar_data

; Set defaults
if not keyword_set(indir) then indir='/disk/hl1/ylegacy/sxtmov23'
if not keyword_set(outdir) then outdir=curdir()
mkfile=keyword_set(mkfile)
nolimit=keyword_set(nolimit)
if not keyword_set(pauz) then pauz=.05 else pauz=pauz
if keyword_set(big) then xsize=1024 else xsize=512
wdef,0,xsize

if not keyword_set(tmin) and not_exist(noaa) then begin
   print,'ERROR.  You must input NOAA AR number or tmin.  Returning.'
   return,''
endif

if exist(noaa) then begin
   ii=where(nar_data.noaa eq strtrim(noaa,2))
   print
   print,'NOAA Active Region number '+strtrim(noaa,2)+$
	' appears for the time interval:'
   fmt_timer,nar_data(ii),tmin,tmax
   if tmin eq tmax then begin
      tx=anytim(tmin)+(24.*60.*60.)
      tmax=anytim(tx,/yoh)
   endif   
   print
endif   

if keyword_set(c_table) then loadct,c_table else loadct,15,/silent

movie_review,stdate=tmin,endate=tmax,indir=indir,mkfile=mkfile,$
	outdir=outdir,nolimit=nolimit,pauz=pauz,$
	header=header,check=check,xsize=xsize,sho_pfi=sho_pfi,$
	one_res=one_res
outstruc=add_tag2(header,0,'check')
if n_elements(check) gt 0 then begin
   outstruc.check=check
   return,outstruc
endif else begin
   return,''
endelse   

end