;+
; NAME:
;     GOES_TEK
; PURPOSE:
;     plot GOES data for Yohkoh CO with Tek graphics
; CATEGORY:
; CALLING SEQUENCE:
;     goes_tek
;     goes_tek, delta
;     goes_tek, t1, t2
;     goes_tek, 24 (the default)
; INPUTS:
;     delta = offset time in hours, ie for a 1-day plot do delta=24 (default)
; OPTIONAL (KEYWORD) INPUT PARAMETERS:
;     ut_offset = puts in a correction for local time (Japan is 9) in the
;                 selection time (plot is still UT)
;     fillsaa = puts SAA times on plot
;     /noclear, don't do clear_utplot at the end.
; OUTPUTS:
; COMMON BLOCKS:
; SIDE EFFECTS:
; RESTRICTIONS:
; MODIFICATION HISTORY:
;     HSH, written 3-Aug-96
;     HSH, ut_offset 6-Dec-96
;     HSH, evt_grid 24-Dec-96
;     TRM, Added GOES classifications and JST times, 1997-Feb-25
;     TRM, Added a call to clear_utplot since the UT plot configuration
;          was left in a strange state.
;     HSH, distinguished DP rates, 15-apr-97
;     HSH, added /fillsaa, 16-May-97
;     HSH, added horizontal lines 10-Oct-97
;     HSH, added /tek keyword 17-Oct-97
;     HSH, put in t1, t2 27-Jan-98
;     HSH, reverted to GOES-8 29-jul-98
;     HSH, fiddled with RD_GXD some more, 12-Sep-98
;     BNH, SSWified and modernized the time calculations, 9-Nov-2000
;     LWA, added keyword noclear, 12-Jun-2009
;-

pro goes_tek, t1, t2, ut_offset = ut_offset, fillsaa=fillsaa, tek=tek, $
	noclear=noclear

noclear=keyword_set(noclear)
case 1 of 
    ; If t1 doesn't exist, then t2 also doesn't exist
    (n_elements(t1) eq 0): $
        time_window, reltime(/now), tstart, tstop, days=[-1, 0], /yohkoh

    ; t1 exists, t2 doesn't
    (n_elements(t2) eq 0): $
        time_window, t1, tstart, tstop, hours=[0, 24], /yohkoh

    ; t1 exists, t2 is number of hours
    (data_chk(t2,/type) eq 2): $
        time_window, t1, tstart, tstop, hours=[0, t2], /yohkoh

; If we make it here, assume t1 and t2 are times
else: begin
          tstart = fmt_tim(t1)
          tstop  = fmt_tim(t2)
      end
endcase

linecolors
if n_elements(ut_offset) eq 0 then ut_offset = 9

delta = fix(ssw_deltat(tstart, tstop)/60/60)
str_delta = strtrim(string(delta),1)

rd_gxd,tstart,tstop,gxd,/five
if n_elements(gxd) lt 10 then rd_gxd,tstart,tstop,gxd,/goes8,/five
utplot_io, gxd, gxd.lo, tit='Last '+str_delta+' hours',$
  yr=[1e-9,1e-3],color=5,/sav,xst=1
if keyword_set(tek) eq 0 then begin
  n_gxd = n_elements(gxd)
  yseed = fltarr(n_gxd)
  outplot,gxd,1e-8+yseed,lines=1
  outplot,gxd,1e-7+yseed,lines=1
  outplot,gxd,1e-6+yseed,lines=1
  outplot,gxd,1e-5+yseed,lines=1
  outplot,gxd,1e-4+yseed,lines=1
  charsize=4.
  csize = convert_coord(!d.x_ch_size,!d.y_ch_size,/device,/to_normal)
  alevel=convert_coord(0.,1.e-8,/data,/to_normal)
  blevel=convert_coord(0.,1.e-7,/data,/to_normal)
  clevel=convert_coord(0.,1.e-6,/data,/to_normal)
  mlevel=convert_coord(0.,1.e-5,/data,/to_normal)
  xlevel=convert_coord(0.,1.e-4,/data,/to_normal)
  xyouts,!x.window(0)-csize(0)*charsize*2.5,alevel(1)-csize(1)*0.6*charsize/2.,'A',/normal,color=!d.n_colors-1,align=0.,charsize=charsize
  xyouts,!x.window(0)-csize(0)*charsize*2.5,blevel(1)-csize(1)*0.6*charsize/2.,'B',/normal,color=!d.n_colors-1,align=0.,charsize=charsize
  xyouts,!x.window(0)-csize(0)*charsize*2.5,clevel(1)-csize(1)*0.6*charsize/2.,'C',/normal,color=!d.n_colors-1,align=0.,charsize=charsize
  xyouts,!x.window(0)-csize(0)*charsize*2.5,mlevel(1)-csize(1)*0.6*charsize/2.,'M',/normal,color=!d.n_colors-1,align=0.,charsize=charsize
  xyouts,!x.window(0)-csize(0)*charsize*2.5,xlevel(1)-csize(1)*0.6*charsize/2.,'X',/normal,color=!d.n_colors-1,align=0.,charsize=charsize
  xy = convert_coord(!x.tickv,replicate(1.0e-3,n_elements(!x.tickv)),/data,/to_normal)
  for i=0,n_elements(!x.tickv)-1 do begin
     if (!x.tickname(i) NE '000') and (!x.tickname(i) NE '') then begin
        tstring = strmid(fmt_tim(anytim2ints(gxd(0),offset=!x.tickv(i)+3600.*9.)),11,5)
        xyouts,xy(0,i),xy(1,i)-csize(1)*1.6,tstring,/normal,align=0.5
     endif
  endfor

  if delta le 48 then begin
    fem_grid,fillsaa=fillsaa
    rd_obs,tstart,tstop,a,b,c
    med = where(gt_dp_rate(b) eq 2, n_med)
    high = where(gt_dp_rate(b) eq 4, n_high)
    if n_med ne 0 then  evt_grid,b(med),tickle=.025,tickpo=.77,color=4
    if n_high ne 0 then evt_grid,b(high),tickle=.05,tickpo=.77,color=4
    med = where(gt_dp_rate(c) eq 2, n_med)
    high = where(gt_dp_rate(c) eq 4, n_high)
    if n_med ne 0 then evt_grid,c(med),tickle=.025,tickpo=.7,color=9
    if n_high ne 0 then evt_grid,c(high),tickle=.05,tickpo=.7,color=9
    flare = where(gt_dp_mode(c) eq 9, n_flare)
    if n_flare ne 0 then evt_grid,c(flare),tickle=.075,tickpo=.86,color=12
  endif
endif

if not noclear then clear_utplot
end