function get_yo_entfilt, index, $
		value=value, verbose=verbose, header=header
;+
; NAME:
;   get_yo_entfilt
;
; PURPOSE:
;   Return significant dates when SXT entrance filter transmission changed.
;       the Value keyword returned the fractional open area.
;   Created to provide the results from the latest calibration, while
;       the GET_YO_DATES kept as it was as of 11-mar-2011.
;
; CALLING SEQUENCE:
;   SXT_ent= get_yo_dates(/entrance)	; Date SXT entrance filter failed
;   SXT_ent= get_yo_dates(/entr,/verbos); Provide additional information
;   SXT_ent= get_yo_dates(/entr,/ver,/head); Provide additional information with header
;   SXT_ent= get_yo_dates(/entr,/value)	; Provide values of entrance filter 
;
; OPTIONAL INPUTS:
;   index	= Standard Yohkoh index or time in any Yohkoh format
;
; OPTIONAL INPUT KEYWORDS:
;   verbose	= Set to return additional information as a string vector
;   value	= Set to return the associated value (rather than the date)
;   header	= If verbose is set, return a header as first element of output 
;			string vector
;
; MODIFICATION HISTORY:
;   24-apr-2015, A. Takeda - prepared as modified version of get_yo_dates.pro.
;-
;
on_error,2		; Return to caller

; ----------- Check the input parameters -----------------

ok = keyword_set(value) + keyword_set(verbose)
if ok gt 1 then message,'/value and /verbose are mutually exclusive'

; ---------------  Set up the data base  ---------------------------
launch_date = '30-Aug-91 10:30:00'              ; Yohkoh Launch date
; ---- Dates of entrance filter changes ----
E_times = [launch_date, fmt_tim('27-Oct-92 07:18'),   $  ; added per L. Acton's final calibration.
                        fmt_tim('13-Nov-92 18:00'),   $
;                           fmt_tim('13-Nov-92 16:50'),     $ ; per L. Acton
                        fmt_tim('1-Aug-93  00:00:00'), $ ; added per L. Acton's final calibration.
                        fmt_tim('16-Aug-95  08:04:20'), $ ; per L. Acton
                        fmt_tim('24-Aug-96  07:00:00'), $
                        fmt_tim('24-Jan-98  00:00:00'), $ ; ESTIMATE
 			fmt_tim('30-Jan-99  23:17'),    $ ; Loren Acton 
                        fmt_tim('12-MAR-99  02:00'), $ ; per L. Acton
                        fmt_tim('20-Apr-99  19:02'),    $ ; per L. Acton
                        fmt_tim('11-Feb-00  13:00:20'),    $ ; Pseduo failure when pointing changed
                        fmt_tim('14-DEC-01  21:12:16')]  ; last SXT + 1sec
; ent_val = [0., 1./12, 2./12,3./12, 4./12, 5./12., 6/12.,7/12.,7/12.]	; Open fraction of entrance filter
ent_val = [0., 0.071, 0.123, 0.128, 0.284, 0.366, 0.455, $
               0.563, 0.622, 0.666, 0.666, 0.666]	; new values per L. Acton's final cal.

; ---------------  Return the requested information ----------------

  if n_elements(index) eq 0 then begin
	times = E_times(0:n_elements(E_times)-1)
	vvv = ent_val
  endif else begin
	times = anytim2ints(index)
	vvv = fltarr(n_elements(times))
	for i=0,n_elements(E_times)-2 do begin
	   ss = sel_timrange(times, E_times(i), E_times(i+1), /between)
	   if ss(0) gt -1 then vvv(ss) = ent_val(i)
	endfor
  endelse
  if keyword_set(verbose) then begin
	outval = strarr(n_elements(times))
	for i=0,n_elements(times)-1 do 	$
	  outval(i) = string(fmt_tim(times(i)),vvv(i),format='(a,f10.4)')
	if keyword_set(header) then outval = ['  Date               Open Fraction of SXT Entrance Filter',outval]
  endif else if keyword_set(value) then begin
	             outval = vvv	
	             if n_elements(vvv) eq 1 then outval = outval(0)
             endif else outval = fmt_tim(times)

return,outval
end