;+
; NAME:
;     GOES2DPE
; PURPOSE:
;     Assess the GOES flux level and recommend AEC settings for SXT.
;     This is meant to be an empirical thing, so please improve the
;     algorithm if you are getting screwy results.
; CATEGORY:
;     goes2dpe
; CALLING SEQUENCE:
; INPUTS:
; OPTIONAL (KEYWORD) INPUT PARAMETERS:
;     test samples the most recent actual SXT data
; OUTPUTS:
; COMMON BLOCKS:
; SIDE EFFECTS:
; RESTRICTIONS:
; MODIFICATION HISTORY:
;     HSH, written 27-Jul-97
;     14-Sep-98, workaround for RD_GXD problem (HSH)
;-
pro goes2dpe, t_ref, test=test, qstop = qstop
dpe = intarr(2,4)
;
; dpe(0,*) is the GOES estimates
; dpe(1,*) is the SXT actuals
;
if n_elements(t_ref) ne 0 then begin
  t_start = anytim2ints(t_ref,off = -24*3600.)
  t_end   = anytim2ints(t_ref)
endif else begin
  t_start = anytim2ints(!stime,off=-(33*3600.))
  t_end = anytim2ints(!stime,off=-(9*3600.))
endelse
rd_gxd,t_start,t_end,gxd,/goes10
if n_elements(gxd) lt 10 then rd_gxd,t_start,t_end,gxd,/goes8
n_data = n_elements(gxd)
sigma = stdev(gxd.lo,goes_mean)
fmt_timer,gxd,t1,t2
rd_obs,t1,t2,a,b,c,/sxtp,/quiet
ss_al = where(gt_filtb(c) eq 2 and gt_expmode(c) eq 0 and gt_res(c) eq 0,n_al)
ss_da = where(gt_filtb(c) eq 3 and gt_expmode(c) eq 0 and gt_res(c) eq 0,n_da)
if n_al ne 0 then org_al = stdev(gt_dpe(c(ss_al)),mean_al) else org_al = 0.
if n_da ne 0 then org_da = stdev(gt_dpe(c(ss_da)),mean_da) else org_da = 0.
if keyword_set(test) then begin
    print,n_data,goes_mean,sigma
    if n_al ne 0 then print,n_al,stdev(gt_dpe(c(ss_al)),mean_al),mean_al
    if n_da ne 0 then print,n_da,stdev(gt_dpe(c(ss_da)),mean_da),mean_da
endif
if n_al ne 0 then dpe(1,2) = fix(mean_al) else dpe(1,2) = fix(mean_da)-2
if n_da ne 0 then dpe(1,3) = fix(mean_da) else dpe(1,3) = fix(mean_al)+2
dpe(1,3) = dpe(1,2)+2
dpe(0,2) = 21 - 5 * (8 + alog10(goes_mean))
dpe(0,3) = dpe(0,2)+2
format = '(a,3x,i2,a,i2)'
print,' '
print,'Recommended initial exposure settings for PFIs:'
print,' '
print,'           GOES   SXT'
print,' '
print,'Thin Al F', format=format,dpe(0,2),'     ',dpe(1,2)
print,'Dagwood F', format=format,dpe(0,3),'     ',dpe(1,3)
print,' '
print,'Thin Al H', format=format,dpe(0,2)-4,'     ',dpe(1,2)-4
print,'Dagwood H', format=format,dpe(0,3)-4,'     ',dpe(1,3)-4
if keyword_set(qstop) then stop
end