;NAME:
;     ffi_head
;PURPOSE:
;     print some of the image header for an FFI image in KSC raw
;       format
;CATEGORY:
;     SXT operation software
;CALLING SEQUENCE:
;     ffi_head, header
;PROGRAM INPUTS:
;     header
;PROGRAM OUTPUTS:
;     prints (to screen) the contents of the image header
;INPUT PARAMETER:
;     None
;COMMON BLOCKS:
;     None
;;SIDE EFFECTS:
;     None.
;Restrictions:
;Modification history:
;     H.Hara Oct 2, 1991
;     HSH 18-jan-96, changed some output stuff
;     HSH 20-jul-96, use SUN2VAX for decoding integers 
;
     pro ffi_head, header, img_time = img_time

;   &&&&&&&&&& READ HEADER INFORMATION &&&&&&&&&&&

print,' '
;   ### Day ###
     day=string(header(52:55)) ;Observed Day
     print,'DAY, mmdd     = '+day
     yy = string((anytim(!stime,/ext))(6))
     img_time = anytim(yy+'/'+strmid(day,0,2)+'/'+strmid(day,2,2))

;   ### DP Mode ###
     h=header(20) 
     case 1 of
        h eq 0: dpmode='Quiet'
        h eq 1: dpmode='Flare'
     endcase
     print,'DP MODE       = '+dpmode

;   ### Bit Rate ###
     h=header(22)
     case 1 of 
        h eq 0: bitrate='High'
        h eq 1: bitrate='Medium'
     endcase
     print,'BIT RATE      = '+bitrate

;    #### DP time #####
     h=long(header,56)
     sun2vax,h
     h=h/1000
     hh=h/3600
     h=h-3600*hh
     mm=h/60
     ss=h-60*mm
     sct      =   strmid(string(hh),10,2)+$
                  ':'+strmid(string(mm),10,2)+$
                  ':'+strmid(string(ss),10,2)
     print,'S/C TIME      = ',sct
     img_time = anytim(img_time + anytim(sct),/yoh)

;    #### Resolution ####

     h=header(89)
     case 1 of
        h eq 0: res='Full'
        h eq 1: res='Half'
        h eq 2: res='Quarter'
     endcase
     print,'RESOLUTION    = '+res

;    #### Exposure Time ####

     hhh = header(80:83)
     hhh = long(hhh,0)
     sun2vax,hhh
     h = hhh/100.
     exposure=h/1000.
     case 1 of
        h lt 1000. : begin
                       exp=strmid(string(h),6,5)
                       c=' ms'
                     end
        h ge 1000. : begin
                       h=h/1000.
                       exp=strmid(string(h),6,5)
                       c=' s'
                     end
     endcase
     print,'EXPOSURE      = '+exp+c


;    #### Filter Information ####

     fila=strmid(string(fix(header(87))),7,1)
     filb=strmid(string(fix(header(88))),7,1)
     print,'B/A           = '+filb+'/'+fila,'   (',gt_filtb(filb,/str),')'


;    #### Exposure Mode ####

     h=fix(header(64))
     exmod=['Normal','Dark  ','Cal  ','Error ']
     print,'EXP           = '+exmod(h)

;    #### Compression Mode ####

     h=fix(header(90))
     com=['Comp','Low ','High']
     print,'COMPRESSION   = '+com(h)

     print,' '



    end