pro fig_sxt_resp, hc=hc, guide=guide, ps=ps
;+
; ROUTINE:
;   fig_sxt_resp
; PURPOSE:
;   Generate the SXT signal vs Temp figure that corresponds to Fig. 9 in
;   the Tsuneta et al Redbook paper.
; CALLING SEQUENCE:
;   plot_sxt_fig9
;   plot_sxt_fig9,/hc		; Send the plot to the printer
;   plot_sxt_fig9,/eps		; Generate a PostScript eps file
;   plot_sxt_fig9,/ps		; Generate a ordinary .ps file
; MODIFICATION HISTORY:
;   15-Dec-93, J. R. Lemen (LPARL), Written
;	16-Dec-93 (MDM) - Replaced /EPS with /GUIDE
;-

clearplot
;
if keyword_set(hc) or keyword_set(guide) or keyword_set(ps) then begin
   set_plot,'ps
   device,xsize=6.,ysize=5.,/inch
   if (keyword_set(guide)) then device, /encapsulated, file='fig_sxt_resp.idlps'
endif

te = 5.5 + findgen(51)*0.05	; Generate Te vector

if !d.name eq 'PS' then font = 0 else font = 1
plot_io,te,sxt_flux(te,1), 						$
		ytitle='SXT SIGNAL (DN/sec for EM=10!U44!N cm!U-3!N)',	$
		xtitle='Log( Temperature )',				$
		charsize=1.5,charthick=2,xthick=2,ythick=2,thick=2,	$
		font=font,						$
		xr=[5.5,8.5],yr=[.01,1000.],/xstyle
			

for i=2,6 do oplot,te,sxt_flux(te,i),thick=2

;  Put on the labels

off = fltarr(7)
off(1) = 40	;open
off(2) =  0	;Al.1
off(3) = -10	;AlMg
off(6) = -5	;Mg3
for i=1,6 do xyouts,8.06,sxt_flux(max(te),i)+off(i),gt_filtb(i,/str),	$
			charsize=1.3 ,charthick=2,/data

if keyword_set(guide) or keyword_set(ps) then device,/close
if not keyword_set(hc) then set_plot,'X
if not keyword_set(guide) then pprint,/reset

end