pro fig_sxt_ratios, hc=hc, eps=eps, ps=ps, xoff=xoff, yoff=yoff, qtest=qtest
;+
; ROUTINE:
;   fig_sxt_ratios
; PURPOSE:
;   Generate the SXT filter ratio plots vs Temp figure 
;
; CALLING SEQUENCE:
;   fig_sxt_ratios
;   fig_sxt_ratios,/hc		; Send the plot to the printer
;   fig_sxt_ratios,/eps		; Generate a PostScript eps file
;   fig_sxt_ratios,/ps		; Generate a ordinary .ps file
; MODIFICATION HISTORY:
;   16-Dec-93, J. R. Lemen (LPARL), Written
;   14-Mar-94, J. R. Lemen (LPARL), 2*Al12/Al.1 curve corrected
;-
xpage = 15 & ypage = 10
if n_elements(xoff) eq 0 then xoff = 3
if n_elements(yoff) eq 0 then yoff = 3

if keyword_set(hc) or keyword_set(eps) or keyword_set(ps) then begin
   set_plot,'ps
   device,/portrait,xsize=xpage,ysize=ypage,xoffset=xoff,yoffset=yoff,	$
			   encapsulate=keyword_set(eps)
endif

te = 5.5 + findgen(51)*0.05	; Generate Te vector

if !d.name eq 'PS' then font = 0 else font = 1
			
charsize0 = .85				; Title  label size
charsize1 = 1.06			; Axis   label size
charsize2 = 1.3				; xyouts label size

clearplot

; ------------------------------------------
;  Plot Filter Ratios
; ------------------------------------------

xtitle= 'Log10(TEMPERATURE )'
ytitle= 'SXT SIGNAL RATIO'
title = 'SXT FILTER RATIOS'

ratio0 = sxt_flux(te,4,version=version)/(2*sxt_flux(te,5))
ratio1 = sxt_flux(te,3)/sxt_flux(te,2)
ratio2 = 2*sxt_flux(te,4)/sxt_flux(te,2)		; 2*Be119/Al.1
plot,te,ratio0,font=font,charsize=charsize0,				$
	xtitle=xtitle, ytitle=ytitle, title=title,			$
	xcharsize=charsize1, ycharsize=charsize1,			$
    	xrange=[5.5,9.],xstyle=1
title2 = '(sre'+version+')'
oplot,te,ratio1
oplot,te,ratio2

xx = max(te) + .05
ttt = [ gt_filtb(4,/str)+'/(2x'+gt_filtb(5,/str)+')',	$
	gt_filtb(3,/str)+'/'+gt_filtb(2,/str),	$
	'2x'+gt_filtb(4,/str)+'/'+gt_filtb(2,/str) ]	; Fixed label - JRL (14-mar-94)

nn  = n_elements(te)
yy  = [ratio0(nn-1),ratio1(nn-1),ratio2(nn-1)]
for i=0,2 do begin
  xyouts,xx,yy(i)-.015,ttt(i),charsize=charsize1,/data,font=font
endfor

if not keyword_set(qtest) and not keyword_set(eps) then begin
  xxc = 6.
  yy  = .85
  yyc = !y.crange(0) + yy * (!y.crange(1)-!y.crange(0))
  xyouts,xxc,yyc,title2,size=charsize1,/data
  xyouts,.35,0.,'(Plotted '+!stime+')',charsize=1.,/normal
endif
pprint,/reset

end