;+
;
; NAME: 
;	CPHOUSE
;
; PURPOSE:  
;	Output housekeeping information.
;
; CATEGORY: 
;	CP diplay
;
; CALLING SEQUENCE: 
;	pro cphouse, hk=hk, ntime=ntime, colo=colo
;
; CALLED BY:  
;	CPTV, CPMOVIE
;
; CALLS TO:  
;	none
;
; INPUTS:
;	HK	: Array of size (224 x N) where N is 1 for single images
;		  and 2 for difference images. Contains the housekeeping
;		  information for the current image(s)
;	NTIME	:  0 means display the house keeping for the normal image 
;		     or base image of a difference display
;		   1 means use the subtraction image values in HK
;	COLO    : -1 means no hard copy allowed
;		   0 means hard copy device is B/W
;		   1 means hard copy device is color
;
; OPTIONAL INPUTS: 
;	none
;
; OUTPUTS:  
;	none
;
; OPTIONAL OUTPUTS: 
;	none
;
; COMMON BLOCKS: 
;	none
;
; SIDE EFFECTS: 
;	none
;
; RESTRICTIONS: 
;	none
;
; PROCEDURE:
;	Writes the house keeping information to the output device.
;	If a difference image, the base image house keeeping is on the
;	left and the subtraction image house keeping is written on the right.
;
; MODIFICATION HISTORY:
;	1991 - Elaine Einfalt (HSTX)
;
;-


pro cphouse, hk=hk, ntime=ntime, colo=colo

x=.05+(.80*ntime)  &  y=.96  &  down=.05  &  skip=.01

if colo eq -1 then fac = 1 else fac=.80
labsiz=1.2*fac   &  valsiz=2*fac 
                     
xyouts, x, y, 'DATE', /normal, size=labsiz  &  y=y-down
iyr = fix(hk(0))   &  idoy = 256*hk(1) + hk(2)
xyouts, x, y, strtrim(iyr,2)+':'+string(idoy,format='(i3.3)'), /normal, $
				size=valsiz
y=y-down- skip
                               
xyouts, x, y, 'TIME', /normal, size=labsiz  &  y=y-down
time = string(fix(hk(20)),format='(i2.2)') + ':' + $
 	string(fix(hk(21)),'(i2.2)') + ':' + string(fix(hk(24)),'(i2.2)')
xyouts, x, y, time, /normal, size=valsiz  &  y=y-down-skip

; get the day and month from day-of-year and year
month = ['Jan', 'Feb', 'Mar', 'Apr', 'May', 'Jun', 'Jul', 'Aug', 'Sep', $
	 'Oct', 'Nov', 'Dec']
nday = intarr(12)  & nday( [0,2,4,6,7,9,11] ) = 31  & nday( [3,5,8,10] ) = 30
ly = float(iyr)/4.  &  if (ly-fix(ly)) eq 0.0 then nday(1)=29 else nday(1)=28
ndt = 0  &  for i = 0,11 do begin
        	ndt = ndt + nday(i)  &  if ndt ge idoy then goto, label1
            endfor
label1:  mth = i  &  idm = idoy-ndt+nday(i)

xyouts, x, y, string(idm,format='(i2.2)')+' '+month(mth), /normal, size=valsiz  
 y=y-down
xyouts, x, y, strtrim(1900+hk(0),2), /normal, size=valsiz  &  y=y-down-skip 

xyouts, x, y, 'FILTER', /normal, size=labsiz  &  y=y-down
fil = ['RED','H-alpha', 'OPEN', 'BLUE', 'WIDE BD', 'GREEN']
ter = ishft(hk(15) and 'e'x,-1)-1
xyouts, x, y, strtrim(fil(ter),2), /normal, size=valsiz  &  y=y-down-skip

xyouts, x, y, 'POLAROID', /normal, size=labsiz  &  y=y-down
pola = ['CLR', '+60 deg',  '-60 deg', '0 deg']
roid = ishft(hk(3) and 'c0'x,-6) 
xyouts, x, y, strtrim(pola(roid),2), /normal, size=valsiz  &  y=y-down-skip

xyouts, x, y, 'SECTOR', /normal, size=labsiz  &  y=y-down
sec = ['SW', 'S', 'SE', 'E', 'NE', 'N', 'NW', 'W']
tor = ishft(hk(14) and '3c'x,-3)
xyouts, x, y, strtrim(sec(tor),2), /normal, size=valsiz  &  y=y-down-skip

xyouts, x, y, 'EXPOSURE', /normal, size=labsiz  &  y=y-down
a=ishft((hk(10) and 'f0'x),-4)
b=ishft((hk(10) and 'f'x),4) + ishft((hk(11) and 'f0'x),-4)
expo= 1.024 * (256*a) + b
xyouts, x, y, strtrim(strmid(expo,1,8),2), /normal, size=valsiz  
y=y-down-skip

xyouts, x, y, 'RESOLUTION', /normal, size=labsiz  &  y=y-down
reso = ['HIGH','LOW']
lution = ishft((hk(3) and '4'x),-2)
xyouts, x, y, strtrim(reso(lution),2), /normal, size=valsiz  &  y=y-down-skip

xyouts, x, y, 'ROLL', /normal, size=labsiz  &  y=y-down
roll = 256*hk(88) + hk(89)
if roll gt 180 then roll = roll - 360
xyouts, x, y, strtrim(roll,2), /normal, size=valsiz  &  y=y-down-skip

end