EIT Software Listings

 

anal
obsolete
response
util

 

Previous Routine
Next Routine

 

Listing of $SSW/soho/eit/idl/util/nrl2eit.pro

 


function nrl2eit,nrlhdr
;+
; NAME:
;	NRL2EIT
;
; PURPOSE:
;       To make a NRL formatted EIT FITS file compatible with EIT software.
;
; CATEGORY:
;	FITS processing
;
; CALLING SEQUENCE:
;       eithdr = nrl2eit(nrlhdr)
;
; INPUTS:  NRL formatted FITS header
;
; KEYWORD PARAMETERS: none
;
; OUTPUTS:
;	FITS header comptaible with EIT software.
;
; COMMON BLOCKS: none.
;
; SIDE EFFECTS: none.
;
; RESTRICTIONS: none.
;
; PROCEDURE:
;          The only changes needed are to add new keywords to the 
;          header which already contains this info. The necessary info
;          is grabbed out and re-written.
;
; MODIFICATION HISTORY:
; 	Written by:  J. Newmark 	Date.  Oct 08 1996
;	2001.6.21, N.Rich - Fixed date_obs and object
;       2002.8.06 J. Newmark, fixed EXPTIME
;	2003.4.22, N.Rich - For MAP compatibility, Fixed date_obs AGAIN; 
;			    added CDELT1,2
;
;-

eithdr = nrlhdr
wave = fxpar(nrlhdr,'SECTOR')
wave = fix(strmid(wave,0,3))
fxaddpar, eithdr,'WAVELNTH',wave
date_obs = fxpar(nrlhdr,'DATE-OBS')+'t'+fxpar(nrlhdr,'TIME-OBS')
fxaddpar, eithdr,'DATE_OBS',anytim2utc(date_obs,/ccsds)
;if eit_fxpar(eithdr,'NAXIS1') + eit_fxpar(eithdr,'NAXIS2') eq 2048 $
actual = eit_fxpar(eithdr,'NAXIS1') + eit_fxpar(eithdr,'NAXIS2')
original = fxpar(nrlhdr,'R2COL') - fxpar(nrlhdr,'R1COL') $
  	  +fxpar(nrlhdr,'R2ROW') - fxpar(nrlhdr,'R1ROW')
IF original EQ 2046 $
   then object = 'Full FOV' else object = 'Partial FOV' 
shrinkage = float(actual)/original
cdelt = eit_pixsize() / shrinkage
fxaddpar, eithdr,'CDELT1',cdelt
fxaddpar, eithdr,'CDELT2',cdelt
fxaddpar, eithdr,'OBJECT',object
fxaddpar, eithdr,'COMMENT','SHUTTER CLOSE TIME = ' +$
    strtrim(fxpar(nrlhdr,'EXP3'),2) + ' s'
fxaddpar, eithdr,'comment','P1_X =    ' + strtrim(fxpar(nrlhdr,'P1ROW'),2)
fxaddpar, eithdr,'comment','P2_X =    ' + strtrim(fxpar(nrlhdr,'P2ROW'),2)
fxaddpar, eithdr,'comment','P1_Y =    ' + strtrim(fxpar(nrlhdr,'P1COL'),2)
fxaddpar, eithdr,'comment','P2_Y =    ' + strtrim(fxpar(nrlhdr,'P2COL'),2)
fxaddpar, eithdr,'HISTORY','Processed at NRL, header converted by NRL2EIT'
return, eithdr
end



Web curator: Frédéric Auchère
Responsible NASA official: Joseph B. Gurman, Facility Scientist, Solar Data Analysis Center
joseph.b.gurman@gsfc.nasa.gov
+1 301 286-4767
NASA Goddard Space Flight Center
Solar Physics Branch / Code 682

Last revised: - Wed May 9 21:45:23 2007- F. Auchère